  10 CLEAR ;CY=16;NT=1
  20 PRINT "       BATTLESTAR
  30 PRINT "       GALACTICA!";PRINT 
  40 PRINT "             OCT 1978"
  50 PRINT "      BY R.J.NITTO"
  60 FOR T=1TO 1000;NEXT T;R=1;NT=1
  70 FOR C=1TO 9;S=3;IF R<1R=1
  80 CLEAR ;BC=248;FC=7
  90 FOR T=1TO 100;X=RND (159)-80
 100 Y=RND (88)-44;BOX X,Y,1,1,1;NEXT T
 110 PRINT "    CEYLON WARSHIP #",#2,C
 120 X=RND (50)-25;Y=RND (30)-15
 130 CY=-40;GOSUB R×10+330
 140 LINE -10,-10,0;BOX H,V,31,6,2
 150 BOX X,Y,19,3,1;BOX X,Y,31,1,1
 160 BOX X,Y+1,7,6,1;BOX X+7,Y,1,1,1
 170 BOX X-7,Y,1,1,1;LINE 10,10,1
 180 LINE 10,-10,0;LINE -10,10,1;H=X;V=Y
 190 IF TR(1)=1 S=S-1;G=0;GOTO 230
 200 IF X=0 IF Y=0 GOSUB 440;GOTO 330
 210 X=X+RND (5)-3;Y=Y+RND (5)-3
 220 X=X-2×JX(1);Y=Y-2×JY(1);GOTO 140
 230 FOR Z=1TO 6;LINE -75,-40, 0;MU=80
 240 LINE 0,0,3;MU=85;LINE 75,-40,0;MU=80
 250 LINE 0,0,3;MU=85;NEXT Z
 260 IF X<3 IF X>-3 IF Y<3 IF Y>-3 GOTO 300
 270 GOSUB 440;IF G=1 GOTO 330
 280 IF S=0 R=R+1;GOTO 330
 290 GOTO 210
 300 FOR Z=1TO 6;BOX X,Y+1,33,10,3
 310 FOR W=55TO 65;MU=W
 320 NEXT W;NEXT Z;R=R+2
 330 R=R-1;NEXT C;GOTO 540
 340 PRINT "     NOVICE - GRADE 1",;RETURN 
 350 PRINT " TECHNICIAN - GRADE 2",;RETURN 
 360 PRINT "      SCOUT - GRADE 3",;RETURN 
 370 PRINT "      CADET - GRADE 4",;RETURN 
 380 PRINT "     RANGER - GRADE 5",;RETURN 
 390 PRINT "   SERGEANT - GRADE 6",;RETURN 
 400 PRINT "    CAPTAIN - GRADE 7",;RETURN 
 410 PRINT "      MAJOR - GRADE 8",;RETURN 
 420 PRINT "    WARRIOR - GRADE 9",;RETURN 
 430 PRINT "   FLEET COMMANDER",;RETURN 
 440 IF X<4 IF X>-4 IF Y<4 IF Y>-4 A=520;G=1;GOTO 460
 450 A=530
 460 FOR W=80TO 62 STEP -3
 470 BOX X+7,Y,83-W,83-W,3;MU=W
 480 BOX X-7,Y,83-W,83-W,3;MU=W-1
 490 NEXT W;BOX X,Y,35,21,2
 500 GOSUB 510;GOSUB A;RETURN 
 510 CY=32
 515 PRINT "                          ";CY=32;RETURN 
 520 PRINT " YOU HAVE BEEN TERMINATED!";RETURN 
 530 PRINT "        HE MISSED!";RETURN 
 540 CLEAR ;PRINT ;PRINT "     CONGRATULATIONS!"
 550 PRINT ;PRINT "      YOU MADE RANK OF"
 560 GOSUB R×10+330
 570 CY=-32;GOSUB 515;CY=-32
 580 NT=0;PRINT " PRESS TRIGGER TO GO AGAIN"
 590 IF TR(1)=0 GOTO 570
 600 GOTO 60
>RUN 
